无忧启动论坛
标题:
一看见变量就完了，求帮忙
[打印本页]
作者:
窄口牛
时间:
2017-5-18 10:24
标题:
一看见变量就完了，求帮忙
dir *-kb*.exe /b /o:n >list1.log
::将补丁文件按照名字排列存放在list1.log文件里
for /f "delims=- tokens=2" %%i in (list1.log) do REG QUERY "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\HotFix\Volume" || dir /b *%%i*.exe >>list.log
::从list1.log文件中取出一个补丁的名字，截取中间的补丁标号（如KB873339），到注册表查询这个是否已经安装了，没有就将其存放到list.log文件里
上面这个筛选该怎么改？
作者:
wintoflash
时间:
2017-5-18 14:19
不懂帮顶
作者:
窄口牛
时间:
2017-5-18 15:29
谢谢。才发现win7的补丁列表注册表里可能还没有。
作者:
freesoft00
时间:
2017-5-18 19:35
本帖最后由 freesoft00 于 2017-5-18 19:41 编辑
for /f "tokens=2" %%a in ('systeminfo^|findstr /i "kb"') do echo %%a
pause
作者:
nttwqz
时间:
2017-5-18 20:18
wmic qfe get hotfixid | findstr /i /v /g:"kblist.txt" /c:"HotfixID"
复制代码
假设需要安装的补丁列表文件是kblist.txt，文件内容格式每行一个补丁名称，类似于KB1234567，则上述命令会显示出没有安装的补丁。
作者:
窄口牛
时间:
2017-5-18 21:26
获取已安装列表这几个方法都米问题
但是筛选还是做不来
作者:
nttwqz
时间:
2017-5-18 21:57
窄口牛 发表于 2017-5-18 21:26
获取已安装列表这几个方法都米问题
但是筛选还是做不来
你都不会举一反三？
wmic qfe get hotfixid >list1.log
dir *kb*.exe /b /o:n | findstr /i /v /g:"list1.txt" /c:"HotfixID"
findstr
/V 只打印不包含匹配的行。
/G:file 从指定的文件获得搜索字符串。
莫非你非要用变量的方法筛选？
作者:
nttwqz
时间:
2017-5-18 22:02
REG QUERY "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\HotFix\Volume" || dir /b *%%i*.exe >>list.log
这句没什么用吧？
是否应该像下面这样写
REG QUERY "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\HotFix\Volume"
/v "%%i"
|| dir /b *%%i*.exe >>list.log
作者:
窄口牛
时间:
2017-5-18 22:48
本帖最后由 窄口牛 于 2017-5-19 08:04 编辑
那倒不是非要变量，达到目的就可以。目的是已经下载的补丁文件昨天可能已经安装过了，今天就不必再安装了。您的结果貌似还要下载那些已经打过却不再现在的文件夹里的补丁。
作者:
窄口牛
时间:
2017-5-19 08:12
原来的
@echo off
::关闭显示信息
cls
echo ================================================
del list.log /q
::删除上次运行后留下的文件
dir *-kb*.exe /b /o:n >list1.log
::将补丁文件按照名字排列存放在list1.log文件里
for /f "delims=- tokens=2" %%i in (list1.log) do REG QUERY "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\HotFix\%%i" || dir /b *%%i*.exe >>list.log
::从list1.log文件中取出一个补丁的名字，截取中间的补丁标号（如KB873339），到注册表查询这个是否已经安装了，没有就将其存放到list.log文件里
echo 现在开始安装补丁
for /f "eol=o eol=O " %%j in (list.log) do echo 正在安装补丁%%j && %%j /quiet /norestart
::从list.log文件中取出一个补丁的名字，利用参数（/quiet /norestart）进行安装无人安装
echo 恭喜你，补丁程序安装完毕
echo 安装了的补丁（list.log）：& type list.log | more
::显示安装了的补丁的列表，more是用来防止补丁过多，分屏显示用的
pause
::暂停让别人看列表
del list1.log /q
::删除使用过的list1.log文件
set /p YN=是否重新启动电脑，以使更改立即生效，强烈建议重新启动电脑[Y/N]?
if "%YN%" == "N" goto :EOF
if "%YN%" == "n" goto :EOF
shutdown -r -t 0
goto :EOF
复制代码
列表是完整名字，注册表是kbxxxxxx，长短不一样，所以筛选不了
作者:
nttwqz
时间:
2017-5-19 11:22
color>list1.log
for /f "delims=" %%a in ('dir *-kb*.exe /b /o:n') do (
setlocal enabledelayedexpansion
set kbname=%%~a
set kbname=!kbname:*-kb=!
for /f "tokens=1 delims=-" %%b in ("!kbname!") do echo kb%%b>>list1.log
endlocal
)
复制代码
用上面的替代下面的
del list.log /q
::删除上次运行后留下的文件
dir *-kb*.exe /b /o:n >list1.log
作者:
nttwqz
时间:
2017-5-19 11:44
其实个人感觉你这搞的太复杂了，装个补丁，不适用或安装过的是会跳过去的，只不过多了补丁解压时间，我想，你应该是想节省时间
作者:
窄口牛
时间:
2017-5-19 12:15
是的，维护通道里放着一堆补丁，每天都会运行，因为单位不是三五天就能所有的机器都开机激发维护通道，所以需要放一段时间。天天安装一堆补丁，影响工作。
作者:
窄口牛
时间:
2017-5-19 12:15
也就是这段时间，过后也就不需要了。
作者:
窄口牛
时间:
2017-7-3 17:00
win7打补丁
@echo off
del list.log /q
dir *-kb*.msu /b /o:n >a.txt
for /f "tokens=2" %%a in ('systeminfo^|findstr /i "kb"') do echo %%a>>1.txt
for /f "delims=^- tokens=1,*" %%a in (1.txt) do (echo %%a>>2.txt)
del 1.txt /q
for /f "delims=^_ tokens=1,*" %%a in (2.txt) do (echo %%a>>b.txt)
del 2.txt /q
findstr /V /I /G:b.txt a.txt > c.txt && move /y c.txt list.log
del *.txt
for /f "eol=o eol=O " %%j in (list.log) do echo 正在安装补丁%%j && start /wait wusa %%j /quiet /norestart
复制代码
xp打补丁
@echo off
del list.log /q
dir *-kb*.exe /b /o:n >a.txt
for /f "tokens=2" %%a in ('systeminfo^|findstr /i "kb"') do echo %%a>>1.txt
for /f "delims=^- tokens=1,*" %%a in (1.txt) do (echo %%a>>2.txt)
del 1.txt /q
for /f "delims=^_ tokens=1,*" %%a in (2.txt) do (echo %%a>>b.txt)
del 2.txt /q
findstr /V /I /G:b.txt a.txt > c.txt && move /y c.txt list.log
del *.txt
for /f "eol=o eol=O " %%j in (list.log) do echo 正在安装补丁%%j && %%j /quiet /norestart
复制代码
接下来看看.net和office补丁
欢迎光临 无忧启动论坛 (http://bbs.wuyou.net./)
Powered by Discuz! X3.3