关于设置ip的批处理

2012yishuihana

在网上找了个批处理，我想实现选择某个选项后，再回到选择界面，如何处理？谢谢 （选项中再加个退出）最好win7 8.1通用

@rem 运行 ： 右键菜单-〉以管理员身份运行
@echo off
title --IP自动设置 --
MODE con: COLS=80 lines=30
color 0a

:menu
cls

echo ----------------------------------
echo       请选择，输入数字按回车
echo ----------------------------------
echo.
echo       设置为公司用IP 请按 1
echo       设置为自动获取 请按 2
echo       设置IE代理     请按 3
echo       清除IE代理     请按 4
echo       查看当前IP     请按 5
echo.

set /p choice=      您的选择：

echo.

if "%choice%"=="1" goto ip1
if "%choice%"=="2" goto ip2
if "%choice%"=="3" goto ie3
if "%choice%"=="4" goto ie4
if "%choice%"=="5" goto ip5

goto menu

:ip1
echo off
echo 公司IP自动设置开始...
echo.
echo 正在设置，请稍后......
netsh interface ipv4 set address name="本地连接" source=static addr=*.*.*.* mask=*.*.*.* gateway=*.*.*.* gwmetric=1
echo 正在添加本机主DNS...
netsh interface ipv4 set dns name="本地连接" source=static addr=*.*.*.* register=PRIMARY
echo 设置完毕,自动退出！
exit

:ip2
echo   取消指定网络配置，请稍等…
echo.
echo   正在设置自动获取IP地址,请稍等…
netsh interface ipv4 set address name="本地连接" source=dhcp
:以上代码设置IP地址自动获取
netsh interface ipv4 set dns name="本地连接" source=dhcp
:以上代码设置DNS自动获取
echo 设置完毕,自动退出！
exit

:ie3
@echo off
echo 开始设置IE代理上网
@rem 172.88.28.10:80 修改为自己要设置的代理以及端口
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 1 /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /d "*.*.*.*:80" /f  
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyOverride /d
@echo 设置代理完毕,自动退出！
exit

:ie4
@echo off
echo 开始清除IE代理设置
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 0 /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /d "" /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyOverride /d "" /f
echo IE代理清除完毕,自动退出！
exit


:ip5
@echo off
cls
color 0A
ipconfig /all
pause >nul
goto menu

不知

1.把ip1~4标签后的最后一条exit命令改为 goto menu
2.在 echo       查看当前IP     请按 5 后插入一行   echo       退出     请按 6
3.在if "%choice%"=="5" goto ip5 插入一行 if "%choice%"=="6"  exit