更改分区盘符的批处理

linqyx · 发表于 2022-7-10 03:18:47

本帖最后由 linqyx 于 2023-9-4 18:23 编辑

更好的作品请看 dos时代菜鸟在 11楼、17楼、20楼和26楼作者的作品，我这个是自己练习弄着玩的，简陋。

功能很单一，方便更改某一分区的盘符。
注意：千万不要更改系统盘符！千万不要更改系统盘符！千万不要更改系统盘符！
两个文件区别：
更改分区盘符操作简单，退出不删除c：盘目录下的更改分区盘符.bat文件，盘符已经存在的话不提示直接退出。

更改分区盘符v1.0

相对另一个操作比较繁琐，除非鼠标x掉批处理，批处理自行退出会自己删掉更改分区盘符.bat文件，如果盘符已经存在会提示重新输入。

dos时代菜鸟 · 发表于 2023-7-29 09:45:27

本帖最后由 dos时代菜鸟于 2023-7-29 09:54 编辑

原来 win10 没有 "fsutil volume querylabel" 这个命令了
取而代之的是 "fsutil fsinfo volumeinfo"

m3.7z (1.38 KB, 下载次数: 9)

用 fsutil 可以显示没有盘符的分区卷对应的卷标，这样操作起来更有针对性一些。

dos时代菜鸟 · 发表于 2022-7-12 09:09:45

关于编码代码页的问题
win10 下

可以用

mode con: cp select=65001

复制代码

把代码页设置为 utf-8

批处理文件另存为 utf-8 编码，文件

运行时，就能完美支持中文 utf-8

dos时代菜鸟 · 发表于 2022-7-11 19:32:48

linqyx 发表于 2022-7-11 16:50
谢谢，学习了。

这个批处理有瑕疵

dos时代菜鸟 · 发表于 2022-7-11 19:25:00

本帖最后由 dos时代菜鸟于 2022-7-11 19:34 编辑

其实批处理，就是把分析各种文本流信息，找出自己需要的，显示出来，形成交互界面，或者自动运行。最终达到想要的目的。

用for /f  配合 if  和 Set 就基本上可以实现文本流信息的分析
下面这个是用  for /f  + if + Set  分析 fsutil volume 指令的输出结果，获取本地电脑各卷盘符和  卷标。
然后，根据用户所选，通过 mountvol 实现对某个卷的盘符装卸和更改。

因为  中文和英文的文本流不一样，所以需要事先用 chcp 437 把代码页设置为  英文，需要交互界面时，再设置为 936.

m2.7z (1.26 KB, 下载次数: 14)

@echo off
setlocal enabledelayedexpansion
title MOUNTVOL 盘符装卸脚本
:main
chcp 437
set n=0
set ltr_s=
for /f "delims=" %%c in ('fsutil volume list') do (
set str1=%%c
rem 对字符串去空格处理
set str1=!str1: =!
if defined m ( rem 如果定义了变量m 说明上一条字符串是一个卷内容，且本行字符串是该卷对应的盘符
if "!str1:~1,1!"==":" ( rem 如果本行字符串第二个字符是：说明是一个有效的盘符
set ltr=!str1:~0,2!
rem 把盘符存入变量 ltr_s 中
set "ltr_s=!ltr_s! !str1:~0,1!"
) else (
set "ltr=*:"
)
for /f "tokens=6 delims= " %%u in ('fsutil volume querylabel !vol!') do (set label=%%u)
rem 设置包含序号的 vol 变量内容，如 vol1 vol2 vol3 vol4 .......
set vol!n!=!m:~-2!. !ltr! !vol! !label!
set m=
set vol=
)
if "!str1:~0,1!"=="" ( rem 如果本行字符串第一个字符是 \ 说明是个卷，把改行信息出入 vol 变量并设置 m 变量
set /a n=!n!+1
set m= !n!
set vol=!str1!
)
)
chcp 936
cls
echo MOUNTVOL 盘符装卸脚本
echo 序号--盘符-----卷------------------------------------------------卷标-----
for /l %%c in (1,1,!n!) do (echo !vol%%c!)
echo ----------------------------------------
echo 已占用盘符!ltr_s!
SET ltr0= A B C D E F G H I J K L M N O P Q R S T U V W X Y Z
for %%c in (!ltr_s!) DO ( set ltr0=!ltr0: %%c=!)
echo 空闲盘符 !ltr0!
echo ----------------------------------------
set x=0
set /p x="请选择一个要操作的卷(1-!n!,默认输入0退出):_"
echo ----------------------------------------
if !x!==0 goto :eof
for %%c in (!x!) do (
if defined vol%%c (
for /f "tokens=1,2,3 delims= " %%x in ('echo !vol%%c!') do (
echo ------------------------------------
echo 你选择了 %%x
echo 对应盘符 %%y
echo 对应卷是 %%z
echo ------------------------------------
rem 以下内容对卷进行盘符装卸操作
if /i "%%y"=="%systemdrive%" (
echo 系统所在卷,盘符不可更改。
pause
goto :end1
)
set ltr_x=
set /p ltr_x="请输入一个新盘符(输入0卸载该卷盘符):_"
if !ltr_x!==0 (
if not "%%y"=="*:" (
mountvol %%y\ /d
) else (
echo 没有盘符,不需要卸载.
pause
)
) else (
set find=0
for %%r in (!ltr0!) do (
if /i "%%r"=="!ltr_x!" (set "find=1")
)
if !find!==1 (
if not "%%y"=="*:" (mountvol %%y\ /d)
mountvol !ltr_x!:\ %%z
) else (
echo 盘符输入错误,不是空闲盘符。
pause
)
)
)
) else (
echo 输入错误,重新来过.
pause
)
)
:end1
goto :main

复制代码

dos时代菜鸟 · 发表于 2022-7-11 19:16:39

aichong168 发表于 2022-7-10 15:48
我一般用系统自带的磁盘管理功能区修改

我通常用自制 diskpart 图形界面脚本完成。

dos时代菜鸟 · 发表于 2022-7-11 19:15:32

linqyx 发表于 2022-7-11 17:17
不仅学习了知识，写批处理的格式也学习了。以前看到的批处理基本都是从每行行首开始，不知怎么缩进。现在 ...

python 习惯了

dos时代菜鸟 · 发表于 2022-7-11 10:01:47

本帖最后由 dos时代菜鸟于 2022-7-11 19:32 编辑

仅供参考

@echo off
setlocal enabledelayedexpansion
title MOUNTVOL 盘符装卸脚本
:main
cls
echo MOUNTVOL 盘符装卸脚本
echo 序号--盘符-----卷-------------------------------------------------
set n=0
set ltr_s=
for /f "delims=" %%c in ('mountvol /l') do (
set str1=%%c
rem 对字符串去空格处理
set str1=!str1: =!
if defined m ( rem 如果定义了变量m 说明上一条字符串是一个卷内容，且本行字符串是该卷对应的盘符
if "!str1:~1,1!"==":" ( rem 如果本行字符串第二个字符是：说明是一个有效的盘符
set ltr=!str1:~0,2!
rem 把盘符存入变量 ltr_s 中
set "ltr_s=!ltr_s! !str1:~0,1!"
) else (
set "ltr=*:"
)
echo !m:~-2!. !ltr! !vol!
rem 设置包含序号的 vol 变量内容，如 vol1 vol2 vol3 vol4 .......
set vol!n!=!m:~-2!. !ltr! !vol!
set m=
set vol=
)
if "!str1:~0,1!"=="" ( rem 如果本行字符串第一个字符是 \ 说明是个卷，把改行信息出入 vol 变量并设置 m 变量
set /a n=!n!+1
set m= !n!
set vol=!str1!
)
)
echo ----------------------------------------
echo 已占用盘符!ltr_s!
SET ltr0= A B C D E F G H I J K L M N O P Q R S T U V W X Y Z
for %%c in (!ltr_s!) DO ( set ltr0=!ltr0: %%c=!)
echo 空闲盘符 !ltr0!
echo ----------------------------------------
set x=0
set /p x="请选择一个要操作的卷(1-!n!,默认输入0退出):_"
echo ----------------------------------------
if !x!==0 goto :eof
for %%c in (!x!) do (
if defined vol%%c (
for /f "tokens=1,2* delims= " %%x in ('echo !vol%%c!') do (
echo ------------------------------------
echo 你选择了 %%x
echo 对应盘符 %%y
echo 对应卷是 %%z
echo ------------------------------------
rem 以下内容对卷进行盘符装卸操作
if /i "%%y"=="%systemdrive%" (
echo 系统所在卷,盘符不可更改。
pause
goto :end1
)
set ltr_x=
set /p ltr_x="请输入一个新盘符(输入0卸载该卷盘符):_"
if !ltr_x!==0 (
if not "%%y"=="*:" (
mountvol %%y\ /d
) else (
echo 没有盘符,不需要卸载.
pause
)
) else (
set find=0
for %%r in (!ltr0!) do (
if /i "%%r"=="!ltr_x!" (set "find=1")
)
if !find!==1 (
if not "%%y"=="*:" (mountvol %%y\ /d)
mountvol !ltr_x!:\ %%z
) else (
echo 盘符输入错误,不是空闲盘符。
pause
)
)
)
) else (
echo 输入错误,重新来过.
pause
)
)
:end1
goto :main

复制代码

dos时代菜鸟 · 发表于 2022-7-11 08:12:44

linqyx 发表于 2022-7-11 01:02
@echo off
mode con cols=40 lines=20
setlocal enabledelayedexpansion

仅供参考

@echo off
setlocal enabledelayedexpansion
:main
cls
echo -------卷列表----------
set n=0
set ltr_s=
for /f "delims=" %%c in ('mountvol') do (
set str1=%%c
rem 对字符串去空格处理
set str1=!str1: =!
if defined m ( rem 如果定义了变量m 说明上一条字符串是一个卷内容，且本行字符串是该卷对应的盘符
if "!str1:~1,1!"==":" ( rem 如果本行字符串第二个字符是：说明是一个有效的盘符
set ltr=!str1:~0,2!
rem 把盘符存入变量 ltr_s 中
set "ltr_s=!ltr_s! !str1:~0,2!"
) else (
set ltr=
)
echo !m:~-2!. !vol! !ltr!
rem 设置包含序号的 vol 变量内容，如 vol1 vol2 vol3 vol4 .......
set vol!n!=!m:~-2!. !vol! !ltr!
set m=
set vol=
)
if "!str1:~0,1!"=="" ( rem 如果本行字符串第一个字符是 \ 说明是个卷，把改行信息出入 vol 变量并设置 m 变量
set /a n=!n!+1
set m= !n!
set vol=!str1!
)
)
echo 已占用盘符：!ltr_s!
set /p x="请选择一个要操作的卷：(1-!n!,输入0退出)"
if !x!==0 goto :eof
for %%c in (!x!) do (
if defined vol%%c (
for /f "tokens=1,2* delims= " %%x in ('echo !vol%%c!') do (
echo ------------------------------------
echo 你选择了 %%x
echo 对应卷是 %%y
echo 对应盘符 "%%z"
echo ------------------------------------
)
) else (
echo 输入错误，重新来过！
)
)
pause
goto :main

复制代码

dos时代菜鸟 · 发表于 2022-7-10 20:16:56

linqyx 发表于 2022-7-10 18:40
pushd 命令可以判断输入的盘符是否已经存在。
我刚学习批处理不久，3.通常我们更需要把没有分配盘符的 ...

慢慢来，不着急，

其实，用 mountvol 可以获取卷列表和盘符列表，你给卷做个编号，让用户选择需要分配盘符的无盘符卷，就可以了。

dos时代菜鸟 · 发表于 2022-7-10 11:17:08

建议：
1.通过 mountvol 或者其他命令获取已存在的盘符列表并显示出来
2.通过已存在的盘符列表判断用户输入是否正确
3.通常我们更需要把没有分配盘符的卷给分配个盘符

		自动登录	找回密码
密码			注册

[原创] 更改分区盘符的批处理

点评