无忧启动论坛

标题: 可固定于任务栏的“显示桌面” [打印本页]

作者: cclgoo 时间: 2022-2-26 00:14
标题: 可固定于任务栏的“显示桌面”
本帖最后由 cclgoo 于 2022-2-26 00:18 编辑

如题

平时想在任务栏弄一个“显示桌面”的图标

感觉有点困难重重，有点棘手无策的感觉

现在，舒心了！~

（想更完整或自己弄，请：点此前往查看/下载）

显示桌面.exe

94.5 KB, 下载次数: 78, 下载积分: 无忧币 -2

作者: lxl1638 时间: 2022-2-26 00:16
多此一举

作者: cclgoo 时间: 2022-2-26 00:23

lxl1638 发表于 2022-2-26 00:16
多此一举

我新人，很多不会的，快捷键也不太懂，只能如此拙笨的方式了！~多多关照

某些情况或各种考虑下需要的时候总会有点用处的

作者: 山里苗哥 时间: 2022-2-26 01:42
点击【任务栏右下角】不就进入桌面了吗！

作者: cclgoo 时间: 2022-2-26 01:52

山里苗哥发表于 2022-2-26 01:42
点击【任务栏右下角】不就进入桌面了吗！

我居然还从没发现有这技能操作！~习惯性W&D了！~谢谢！~这EXE是给某些特殊特定情况用的

作者: maghreb 时间: 2022-2-26 05:45
win+d

作者: ylac 时间: 2022-2-26 07:54
自带右下角不是就可进入桌面

作者: temp2005 时间: 2022-2-26 08:16
好像没啥用

作者: liuzhaoyzz 时间: 2022-2-26 09:28
赞一个，很小巧的程序，long long ago我也写过这样子的程序。虽然任务栏最右侧有显示桌面的功能，但是有时候还是习惯左侧的快速启动区，因为这里可以快速地调用其他程序。

作者: 2012andyle113 时间: 2022-2-26 11:04
现在说实在的有点多余了，新的系统只要资源管理器存在就不会没有的

作者: aaalp 时间: 2022-2-26 11:05
感谢你的分享！

作者: ddzyhhh 时间: 2022-2-26 18:11
本帖最后由 ddzyhhh 于 2022-2-27 17:23 编辑

右键/新建快捷方式/输入“C:\Windows\explorer.exe shell:::{3080F90D-D7AD-11D9-BD98-0000947B0257}”

......

显示桌面.rar

1.14 KB, 下载次数: 9, 下载积分: 无忧币 -2

作者: wsdyleon 时间: 2022-2-26 19:30
系统不是从7就带这个功能了吗？不过平常不太用，没多大用对于我，当然有时候我也用

作者: qj585800753 时间: 2022-2-27 00:24
十万火急【发不了求助帖权限不够特在此求助】

同样的镜像ESD格式在其它非10代之前CPu安装征程启动在11代英特CPU PE 下安装好后重启蓝屏
如果是官方原版IOS 双击打开按照官方的安装正常启动这是安装工具问题还是 CPU 限制问题

作者: cclgoo 时间: 2022-2-27 02:10

ddzyhhh 发表于 2022-2-26 18:11
右键/新建快捷方式/输入“C:\Windows\explorer.exe shell:::{3080F90D-D7AD-11D9-BD98-0000947B0257}”

...

这比BAT出来的慢，卡卡的！~

作者: 牧心山水 时间: 2022-2-27 16:01
感谢分享

作者: ljyljx 时间: 2022-2-27 16:55
C:\Users\Administrator\AppData\Roaming\Microsoft\Internet Explorer\Quick Launch

系统这个目录下不是有“显示桌面”的快捷方式吗？

作者: ddzyhhh 时间: 2022-2-27 17:24

cclgoo 发表于 2022-2-27 02:10
这比BAT出来的慢，卡卡的！~

我这里是秒刷新，甚至不到1秒。

作者: fxssj 时间: 2022-2-27 17:37
谢谢分享

作者: zy522000 时间: 2022-2-27 19:40
用快捷键不好吗？win+d

作者: zy522000 时间: 2022-2-27 19:43

edison_2008 发表于 2022-2-26 10:24
WIN+M

你这个是最小化快捷键，不是显示桌面快捷键。显示桌位是WIN+D，用你这个，如果桌面上有没有最小化的窗口，是不会缩到任务栏的。
比如你用WIN+R,把运行窗口调出来，试一下就知道了。

作者: ldtwh01 时间: 2022-2-28 14:53
新建一个批处理文件，内容如下：

@echo off
:QuanXian
::为当前批处理脚本获取管理员权限。
1>nul 2>nul reg query HKU\S-1-5-19
if %errorlevel%==0 goto :Admin
pushd %~DP0 & cd /d "%~dp0"
%1 %2
mshta vbscript:createobject("shell.application").shellexecute("%~s0","goto :Admin","","runas",1)(window.close)&goto :eof

:Admin
::切换当前目录至批处理文件所在位置。
cd /d %~dp0
::开启延迟环境变量扩展。
setlocal EnableDelayedExpansion

:ShuoMing
::清理屏幕。
cls
::设置窗口尺寸【80列15行】。
mode con cols=80 lines=15
::设置背景颜色【0黑色】、文字颜色【7白色】。
color 07

:生成【显示桌面】命令文件（%windir%与%SystemRoot%在此处等效）
echo [Shell] >"%windir%\显示桌面.scf"
echo Command=2 >>"%windir%\显示桌面.scf"
echo IconFile=explorer.exe,3 >>"%windir%\显示桌面.scf"
echo. >>"%windir%\显示桌面.scf"
echo [Taskbar] >>"%windir%\显示桌面.scf"
echo Command=ToggleDesktop >>"%windir%\显示桌面.scf"

:为【显示桌面】创建快捷方式
echo Dim WshShell,Shortcut >%TEMP%\tmp.vbs
echo Dim path,fso >>%TEMP%\tmp.vbs
echo path="%windir%\显示桌面.scf" >>%TEMP%\tmp.vbs
echo Set fso=CreateObject("Scripting.FileSystemObject") >>%TEMP%\tmp.vbs
echo Set WshShell=WScript.CreateObject("WScript.Shell") >>%TEMP%\tmp.vbs
echo Set Shortcut=WshShell.CreateShortCut("%UserProfile%\AppData\Roaming\Microsoft\Internet Explorer\Quick Launch\User Pinned\TaskBar\显示桌面.lnk") >>%TEMP%\tmp.vbs
echo Shortcut.TargetPath=path >>%TEMP%\tmp.vbs
echo Shortcut.Save >>%TEMP%\tmp.vbs
call %TEMP%\tmp.vbs
del /f /s /q %TEMP%\tmp.vbs

:通过注入注册表键值，将【显示桌面】固定到任务栏
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Taskband" /v "Favorites" /t REG_BINARY /d "00940100003a001f80c827341f105c1042aa032ee45287d668260001002600efbe12000000ea7e1e67b227d801e0562875b227d8013fa40aeaff29d801140056003100000000005954312311005461736b42617200400009000400efbe5654ec30595433232e000000dd8e000000000100000000000000000000000000000074380a005400610073006b0042006100720000001600020136004903000059545b2320003e663a794c6862972e006c006e006b000000420009000400efbe59545b2359545b232e0000004c9a0000000006000000000000000000000000000000c156c0003e663a794c6862972e006c006e006b0000002000220000001e00efbe02005500730065007200500069006e006e006500640000002000120000002b00efbe3fa40aeaff29d80120006c0000001d00efbe02007b00460033003800420046003400300034002d0031004400340033002d0034003200460032002d0039003300300035002d003600370044004500300042003200380046004300320033007d005c003e663a794c6862972e00650078006500000020000000ff" /f
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Taskband" /v "FavoritesResolve" /t REG_BINARY /d "300300004c0000000114020000000000c00000000000004683008000200000003fa40aeaff29d8013fa40aeaff29d8013fa40aeaff29d80149030000000000000100000000000000000000000000000094013a001f80c827341f105c1042aa032ee45287d668260001002600efbe12000000ea7e1e67b227d801e0562875b227d8013fa40aeaff29d801140056003100000000005954312311005461736b42617200400009000400efbe5654ec30595433232e000000dd8e000000000100000000000000000000000000000074380a005400610073006b0042006100720000001600020136004903000059545b2320003e663a794c6862972e006c006e006b000000420009000400efbe59545b2359545b232e0000004c9a0000000006000000000000000000000000000000c156c0003e663a794c6862972e006c006e006b0000002000220000001e00efbe02005500730065007200500069006e006e006500640000002000120000002b00efbe3fa40aeaff29d80120006c0000001d00efbe02007b00460033003800420046003400300034002d0031004400340033002d0034003200460032002d0039003300300035002d003600370044004500300042003200380046004300320033007d005c003e663a794c6862972e00650078006500000020000000a50000001c000000010000001c0000003300000000000000a40000001700000003000000a91a920e1000000053797374656d00433a5c55736572735c41646d696e6973747261746f725c417070446174615c526f616d696e675c4d6963726f736f66745c496e7465726e6574204578706c6f7265725c517569636b204c61756e63685c557365722050696e6e65645c5461736b4261725ccfd4cabed7c0c3e62e6c6e6b000060000000030000a058000000000000006465736b746f702d336a62313663760000000000000000000000000000000000231e98cccb95ec11a98600808e8a8fab00000000000000000000000000000000231e98cccb95ec11a98600808e8a8fab45000000090000a03900000031535053b1166d44ad8d7048a748402ea43d788c1d0000006800000000480000004f5ae3f6a45cd94babe58be29f40522a000000000000000000000000" /f

:提示并重启资源管理器进程使得修改操作生效
cls
echo.
echo.
echo 添加【显示桌面】操作完成，按任意键后将重启资源管理器进程，从而令操作生效。
pause
taskkill /f /im explorer.exe
start explorer.exe

执行后会固定显示桌面图标到任务栏（副作用是原有的固定图标会被清除，所以建议在系统刚安装完毕时使用），Win10经测试是有效的。

作者: ldtwh01 时间: 2022-3-2 12:51
最新的添加【显示桌面】图标到任务栏的脚本如下（现在已经不会造成原有的固定图标清空了）：

@echo off
:QuanXian
::为当前批处理脚本获取管理员权限。
1>nul 2>nul reg query HKU\S-1-5-19
if %errorlevel%==0 goto :Admin
pushd %~DP0 & cd /d "%~dp0"
%1 %2
mshta vbscript:createobject("shell.application").shellexecute("%~s0","goto :Admin","","runas",1)(window.close)&goto :eof

:Admin
::切换当前目录至批处理文件所在位置。
cd /d %~dp0
::开启延迟环境变量扩展。
setlocal EnableDelayedExpansion
::参数变量初始化。
::⑴固定到任务栏的【显示桌面】功能文件的文件名（可根据个人习惯修改）。
set FileName=显示桌面
::⑵固定到任务栏的【显示桌面】功能文件的位置（可根据个人习惯修改）。
set FilePath=%windir%
::⑶固定到任务栏的快捷方式存储位置（操作系统的默认设置一般不做修改）。
set PinPath=%UserProfile%\AppData\Roaming\Microsoft\Internet Explorer\Quick Launch\User Pinned\TaskBar
::⑷根据前面三项变量，设置相关变量。
set ExeFile=%FilePath%\%FileName%.exe
set ScfFile=%FilePath%\%FileName%.scf
set ShortcutName=%FileName%.lnk
set ShortcutFile=%PinPath%\%ShortcutName%

:ZhuJieMian
::清理屏幕。
cls
::设置窗口尺寸【80列15行】。
mode con cols=80 lines=15
::设置背景颜色【0黑色】、文字颜色【7白色】。
color 07
::设置窗口标题栏显示内容。
title 【脚本制作人：超能虎爸】
::显示主菜单选项。
echo.
echo          ************************************************************
echo          *             任务栏【显示桌面】图标添加脚本             *
echo          *          【适用系统：windows 7 及以上版本】          *
echo          ************************************************************
echo.
echo          本脚本添加【显示桌面】按钮后，为使图标显示正常，会重启资源
echo          管理器进程，请注意文件保存。因为没有及时保存所造成的重要资
echo          料丢失，脚本制作人概不负责！
echo          （任务栏已有的同名图标会被取消，需再执行一次脚本进行固定。）
echo.
echo       ==================================================================
echo.
choice /c yn /n /m ">       输入【Y】执行脚本，输入【N】退出操作："
::根据选择结果【进入执行环节】或【退出脚本】。
if %errorlevel%==1 call :ZhiXing
if %errorlevel%==2 exit

:ZhiXing
::检测是否存在同名快捷方式
if exist "%ShortcutFile%" (del /f /s /q "%ShortcutFile%")
::生成【显示桌面】的exe文件。
echo [Shell] >%ExeFile%
echo Command=2 >>%ExeFile%
echo IconFile=explorer.exe,3 >>%ExeFile%
echo. >>%ExeFile%
echo [Taskbar] >>%ExeFile%
echo Command=ToggleDesktop >>%ExeFile%
::将【显示桌面.exe】固定到任务栏。
::增加固定到任务栏的临时右键菜单。
mshta VBScript:Execute("Set ObjShell=CreateObject(""WScript.Shell""):ObjShell.RegWrite ""HKEY_CURRENT_USER\Software\Classes\*\shell\{:}\ExplorerCommandHandler"", ObjShell.RegRead(""HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\CommandStore\shell\Windows.taskbarpin\ExplorerCommandHandler""), ""REG_SZ"":close")
::用增加临时右键菜单将【显示桌面.exe】固定到任务栏。
mshta VBScript:Execute("Set ObjApp=CreateObject(""Shell.Application""):Set ObjFolder=ObjApp.Namespace(""%FilePath%\""):Set ObjFile=ObjFolder.ParseName(""%FileName%.exe""):ObjFile.InvokeVerb(""{:}""):close")
::删除增加的临时右键菜单。
mshta VBScript:Execute("Set ObjShell=CreateObject(""WScript.Shell""):ObjShell.RegDelete ""HKEY_CURRENT_USER\Software\Classes\*\shell\{:}\"":close")
::修改【显示桌面.exe】的扩展名为scf。
rename %ExeFile% %FileName%.scf
::修改之前生成的快捷方式到正确目标。
cd /d %PinPath%
mshta VBScript:Execute("Set ObjShell=CreateObject(""WScript.Shell""):Set Link=ObjShell.CreateShortcut(""%ShortcutName%""):Link.TargetPath=""%ScfFile%"":Link.WorkingDirectory=""%FilePath%"":Link.Save:close"^)
cd /d %~dp0
::提示并重启资源管理器进程使得修改操作生效
cls
echo.
echo       ==================================================================
echo          本脚本添加【显示桌面】按钮后，为使图标显示正常，会重启资源
echo          添加【显示桌面】操作已完成，为使其图标显示正常，需要重启资
echo          源管理器进程，请注意保存文件以防造成损失。
echo             （若不重启进程，之后自行注销或重启系统也可达到相同效果）
echo       ==================================================================
echo.
echo       【Y】立即重启资源管理器进程。
echo       【N】暂不重启资源管理器进程。
echo.
choice /c yn /n /m ">       请选择要进行的操作［Y/N］："
if %errorlevel%==2 goto :ZhuJieMian

taskkill /f /im explorer.exe
start explorer.exe

exit

作者: nowayer 时间: 2023-10-20 20:38
提示: 作者被禁止或删除内容自动屏蔽

欢迎光临无忧启动论坛 (http://bbs.wuyou.net./)