无忧启动论坛

标题: {已解决}批处理多选菜单问题 [打印本页]
作者: 2011qx    时间: 2016-12-11 21:59
标题: {已解决}批处理多选菜单问题
本帖最后由 2011qx 于 2016-12-20 17:30 编辑

鉴于用 set /p ID=
if "%id%"=="1"
方式 最大的缺点就是输入英文的双引号“ " ”或是拖拽带空格的文件到窗口都会退出，

谢谢各位帮忙，搞定了

在次说声谢谢
作者: 不知    时间: 2016-12-11 23:00
本帖最后由 不知 于 2016-12-12 11:10 编辑

问题2：
可以用if defined (变量名) （命令）



比如说：
在菜单选择时
set menu1=[随便的字符串（无空格）]
在后面用
if defined menu1 [处理命令]
缺点是菜单只能选一次，如果要处理多次可以用
if defined menu1 if %menu1%==[特定的字符串（无空格）]
————————————————————————————————————-
菜单示例：

@echo off

rem 清空以前的选择。
for /L %%i in (1,1,20) do if defined menu%%i set menu%%i=


rem 此处显示菜单
:menu
echo 1.menu1 2.menu2 3.menu3 4.menu4 ...

set /p id=请输入数字（输入Y执行,输入N+数字取消选择）:
if not defined id (
echo 请选择菜单
cls
goto :menu
)
if defined id (
if /I %id:~,1%==N set menu%id:~1%=
set menu%id%=1
set id=
if /I not  %id%==Y  goto :menu

)


rem 此处添加处理
for /L %%i in (1,1,20) do if defined menu%%i (
echo 你选择了menu%%i
call :menu%%i
)


goto :EOF

rem 子菜单区

:menu1
echo 1
pause
goto :EOF

:menu2
echo 2
pause
goto :EOF

:menu3
echo 3
pause
goto :EOF

:menu4
echo 4
pause
goto :EOF

rem 更多子菜单....



菜单多选.7z (475 Bytes, 下载次数: 11)







作者: slore    时间: 2016-12-11 23:04

  2. @echo off

  4. set OPT_CHECKED_ALL=0
  5. call :OPT_CHECKED_SET ○

  7. :CHOOSE_MENU
  8. set option=
  9. set fixed_option=
  10. echo ===Menu===
  11. echo =%OPT1_CHECKED% 1. 选项1=
  12. echo =%OPT2_CHECKED% 2. 选项2=
  13. echo =%OPT3_CHECKED% 3. 选项3=
  14. echo =%OPT4_CHECKED% 4. 选项4=
  15. echo =%OPT5_CHECKED% 5. 全选/取消选择=
  16. echo =%OPTOK_CHECKED% OK. 下一步=
  17. set /p option=请选择功能,选择完成后请输入OK进行下一步:

  19. rem 替换引号为空
  20. if not "x%option%"=="x" set fixed_option=%option:"=%

  22. if "x%fixed_option%"=="x" (
  23.   goto :CHOOSE_MENU
  24. )

  26. if "x%fixed_option%"=="x1" (
  27.   if [%OPT1_CHECKED%]==[○] (set OPT1_CHECKED=●) else (set OPT1_CHECKED=○)
  28.   goto :CHOOSE_MENU
  29. )
  30. if "x%fixed_option%"=="x2" (
  31.   if [%OPT2_CHECKED%]==[○] (set OPT2_CHECKED=●) else (set OPT2_CHECKED=○)
  32.   goto :CHOOSE_MENU
  33. )
  34. if "x%fixed_option%"=="x3" (
  35.   if [%OPT3_CHECKED%]==[○] (set OPT3_CHECKED=●) else set OPT3_CHECKED=○
  36.   goto :CHOOSE_MENU
  37. )
  38. if "x%fixed_option%"=="x4" (
  39.   if [%OPT4_CHECKED%]==[○] (set OPT4_CHECKED=●) else set OPT4_CHECKED=○
  40.   goto :CHOOSE_MENU
  41. )
  42. if "x%fixed_option%"=="x5" (
  43.   if %OPT_CHECKED_ALL%==0 (
  44.     call :OPT_CHECKED_SET ●
  45.     set OPT_CHECKED_ALL=1
  46.   ) else (
  47.     call :OPT_CHECKED_SET ○
  48.     set OPT_CHECKED_ALL=0
  49.   )
  50.   goto :CHOOSE_MENU
  51. )
  52. if /i "x%fixed_option%"=="xOK" (
  53.   goto :MAIN
  54. )

  56. goto :CHOOSE_MENU

  58. :MAIN
  59. if %OPT1_CHECKED%==● echo 你选择了1
  60. if %OPT2_CHECKED%==● echo 你选择了2
  61. if %OPT3_CHECKED%==● echo 你选择了3
  62. if %OPT4_CHECKED%==● echo 你选择了4
  63. pause
  64. goto :EOF

  66. :OPT_CHECKED_SET
  67. for /l %%i in (1,1,4) do set OPT%%i_CHECKED=%1
  68. goto :EOF


复制代码


如果启用变量延时的话，代码可以精简些，不过作为例子这样容易懂些。
作者: 2011qx    时间: 2016-12-12 11:48
慢慢研究下谢谢
作者: 2011qx    时间: 2016-12-14 10:53
不知 发表于 2016-12-11 23:00
问题2：
可以用if defined (变量名) （命令）

谢谢你的帮助，我现在在吧批处理做完，做玩后就来专搞这2个问题
作者: 2011qx    时间: 2016-12-16 09:58
slore 发表于 2016-12-11 23:04
如果启用变量延时的话，代码可以精简些，不过作为例子这样容易懂些。

你这个好像只能选一个啊
作者: 2011qx    时间: 2016-12-16 16:03
slore 发表于 2016-12-11 23:04
如果启用变量延时的话，代码可以精简些，不过作为例子这样容易懂些。

你这个菜单还是不错的哈哈谢谢，可以帮我看看choice菜单形式的不，这种不会输入特殊字符退出
作者: 不知    时间: 2016-12-18 12:30
变量表达式等号的作用。


作者: slore    时间: 2016-12-18 16:34
本帖最后由 slore 于 2016-12-18 16:46 编辑
  1. rem 替换引号为空
  2. if not "x%option%"=="x" set fixed_option=%option:"=%
复制代码


输入单个引号程序退出的原因是，这里用了比较。本来是应对啥都不输入直接回车的情况，结果输入"比较语句就错了，还轮不到替换。

解决方法有2个，第一个方法:给option设置初始值，这样就不用判空了，直接判断是初始值再回到菜单。
第二个方法:判断是否有输入改为define来判断，不牵扯获取option的值，这样不会引用option的内容"导致语法错误。
  1. rem 替换引号为空
  2. if DEFINED option set fixed_option=%option:"=%
复制代码


另外使用变量延时简化判断的代码完整如下:
  1. @echo off
  2. SETLOCAL  ENABLEDELAYEDEXPANSION

  4. set OPT_CHECKED_ALL=0
  5. call :OPT_CHECKED_SET ○

  7. set MAX_OPT=4

  9. :CHOOSE_MENU
  10. set option=
  11. set fixed_option=
  12. echo ===Menu===
  13. echo =%OPT1_CHECKED% 1. 选项1=
  14. echo =%OPT2_CHECKED% 2. 选项2=
  15. echo =%OPT3_CHECKED% 3. 选项3=
  16. echo =%OPT4_CHECKED% 4. 选项4=
  17. echo =%OPT5_CHECKED% 5. 全选/取消选择=
  18. echo =%OPTOK_CHECKED% OK. 下一步=
  19. set /p option=请选择功能,选择完成后请输入OK进行下一步:

  21. rem 替换引号为空
  22. if DEFINED option set fixed_option=%option:"=%

  24. if "x%fixed_option%"=="x" (
  25.   goto :CHOOSE_MENU
  26. )

  28. set /a opt_n=0
  29. :OPT_CHECK_LOOP
  30. if "x%fixed_option%"=="x%opt_n%" (
  31.   if [!OPT%opt_n%_CHECKED!]==[○] (set OPT%opt_n%_CHECKED=●) else (set OPT%opt_n%_CHECKED=○)
  32.   goto :CHOOSE_MENU
  33. )
  34. set /a opt_n+=1
  35. if %opt_n% GTR %MAX_OPT% goto :OUT_OPT_CHECK
  36. goto :OPT_CHECK_LOOP


  39. :OUT_OPT_CHECK
  40. if "x%fixed_option%"=="x5" (
  41.   if %OPT_CHECKED_ALL%==0 (
  42.     call :OPT_CHECKED_SET ●
  43.     set OPT_CHECKED_ALL=1
  44.   ) else (
  45.     call :OPT_CHECKED_SET ○
  46.     set OPT_CHECKED_ALL=0
  47.   )
  48.   goto :CHOOSE_MENU
  49. )
  50. if /i "x%fixed_option%"=="xOK" (
  51.   goto :MAIN
  52. )

  54. goto :CHOOSE_MENU

  56. :MAIN
  57. if %OPT1_CHECKED%==● echo 你选择了1
  58. if %OPT2_CHECKED%==● echo 你选择了2
  59. if %OPT3_CHECKED%==● echo 你选择了3
  60. if %OPT4_CHECKED%==● echo 你选择了4
  61. pause
  62. goto :EOF

  64. :OPT_CHECKED_SET
  65. for /l %%i in (1,1,%MAX_OPT%) do set OPT%%i_CHECKED=%1
  66. goto :EOF
复制代码
作者: devilma    时间: 2016-12-18 17:39
不错的说，学习了。。。。
作者: 2011qx    时间: 2016-12-20 17:27
slore 发表于 2016-12-18 16:34
输入单个引号程序退出的原因是，这里用了比较。本来是应对啥都不输入直接回车的情况，结果输入"比较语 ...

英文双引号问题搞定了， 利用了转译符  ……就可以了
作者: uJtzY514    时间: 2017-1-11 20:06
我依旧站在这古老的战场上，糊了一把乱风向。



欢迎光临 无忧启动论坛 (http://bbs.wuyou.net./) Powered by Discuz! X3.3