无忧启动论坛

标题: 做了一個一鍵還原PE光盤，遇到一些問題 [打印本页]

作者: 2872301721 时间: 2014-5-7 21:43
标题: 做了一個一鍵還原PE光盤，遇到一些問題
本帖最后由 2872301721 于 2014-5-7 22:00 编辑

大家好!我用WIN AIK 做了一個WINPE 裡面放了ImageX 和一個批次檔(cmd)
現在在虛擬機裡面已能做到備份還原比Ghost 快多了
想要取代現在用的SRC一鍵還原  GHOST
且越簡單越好，所以採用批次檔處理

遇到的問題是
1.目前僅能用光盤方式啟動，還無法裝到硬盤，還在測試
2.還未找到方法用批次修改MBR將磁區隱藏(無法實現一鍵載入還原系統)

大家一起看看還有什麼地方可以改得

PS:慣用語系為繁體中文
以下為新增修改的內容

修改Windows\system32\startnet.cmd 內容
====================================
wpeinit
Imagex.cmd
====================================

新增Windows\system32\Imagex.cmd
====================================
@echo off

cls
rem 更換顏色為紅底黑字
color 40
echo.
ECHO    ========================================
Echo    如無系統備份檔，僅進入備份模式
ECHO    ========================================
echo.
Pause

:start
cls
rem 更換顏色為藍底白字
color 1f
IF NOT EXIST d:\Win.wim  goto Backup
echo.
ECHO       備份/還原系統
Echo.
ECHO    ========================================
ECHO    1. 還原我的電腦系統
ECHO    -----------------------------------------
ECHO    2. 備份我的電腦系統
ECHO    ========================================
ECHO    Q. 重新開機
echo.
SET Choice=
SET /P Choice= 請選擇要進行的操作（1/2/Q），然後按確定：
ECHO.
rem Set 將抽出 Choice 變數的第一個字元。
IF NOT '%Choice%'=='' SET Choice=%Choice:~0,1%
IF /I '%Choice%'=='1' GOTO Restore
IF /I '%Choice%'=='2' GOTO Backup
IF /I '%Choice%'=='Q' GOTO End
GOTO Start

:Restore
cls
SET Choice=
SET /P Choice= 要進行還原，請輸入"yes"，然後按確定，並請勿中斷電源，：
IF NOT '%Choice%'=='' SET Choice=%Choice:~0,3%
IF NOT '%Choice%'=='yes' goto start
format c: /fs:NTFS /q /y
start /wait imagex /APPLY D:\Win.wim 1 C:
bootsect /nt60 c:
goto end

:Backup
cls
echo.
ECHO       備份/還原系統
Echo.
ECHO    ========================================
ECHO    1. 無壓縮備份
ECHO    -----------------------------------------
ECHO    2. 快速備份
ECHO    -----------------------------------------
ECHO    3. 高壓縮備份
ECHO    ========================================
ECHO    Q. 回上一層
echo.
SET Choice=
SET /P Choice= 請選擇要進行的操作（1/2/3/Q），然後按確定：
ECHO.
IF NOT '%Choice%'=='' SET Choice=%Choice:~0,1%
IF /I '%Choice%'=='1' GOTO Backup1
IF /I '%Choice%'=='2' GOTO Backup2
IF /I '%Choice%'=='3' GOTO Backup3
IF /I '%Choice%'=='Q' GOTO Start
GOTO Backup

:Backup1
cls
SET Choice=
SET /P Choice= 要進行備份，請輸入"yes"，然後按確定，並請勿中斷電源，：
IF NOT '%Choice%'=='' SET Choice=%Choice:~0,3%
IF NOT '%Choice%'=='yes' goto Backup
start /wait imagex /compress None /capture C: D:\Win.wim "Win_XP_wim"
goto end

:Backup2
cls
SET Choice=
SET /P Choice= 要進行備份，請輸入"yes"，然後按確定，並請勿中斷電源，：
IF NOT '%Choice%'=='' SET Choice=%Choice:~0,3%
IF NOT '%Choice%'=='yes' goto Backup
start /wait imagex /compress fast /capture C: D:\Win.wim "Win_XP_wim"
goto end

:Backup3
cls
SET Choice=
SET /P Choice= 要進行備份，請輸入"yes"，然後按確定，並請勿中斷電源，：
IF NOT '%Choice%'=='' SET Choice=%Choice:~0,3%
IF NOT '%Choice%'=='yes' goto Backup
start /wait imagex /compress maximum /capture C: D:\Win.wim "Win_XP_wim"
goto end

:End
cls
echo.
ECHO       退出備份/還原系統
Echo.
Pause
exit
====================================

新增 windows\system32\imagex.exe

ISO http://pan.baidu.com/s/1dDw0YkT

欢迎光临无忧启动论坛 (http://bbs.wuyou.net./)